윈도우10 제품 키 확인 방법

윈도우 10을 설치하고 나서, 설치했던 정품 설치 키를 잊어버린 경우가 있습니다. 한두 푼 하는 키가 아니라서 잃어버리면 안 되기 때문에 현재 OS에서 윈도우 제품 키를 확인하는 방법을 알아보겠습니다.

 

 

CD 키, 제품 키, 정품 키 ,설치 키, 인증 키 등 다양하게 불리는 제품 키는 소프트웨어에서 Product Key로 표시되어 있으니 본 글에서는 제품 키로 부르겠습니다.

 

윈도우 10의 제품키를 알아내는 방법은 4가지로, 아래 자세히 설명했습니다. 이 방법은 자신의 윈도우 설치 상태에 따라 동작 여부가 다릅니다. 아래 방법을 해보고 안되면 다른 방법으로 윈도우 10 제품키를 확인해야 합니다.

 

 

 

 

- 목차 -

방법1 - VBS 프로그램으로 윈도우 10 제품키 알아내기

방법2 - 키 확인 프로그램으로 윈도우 10 제품키 확인하기

방법3 - 레지스트 정보에서 윈도우 10 제품키 알아내기

방법4 - 브랜드 PC, 노트북을 위한 윈도우 제품키 확인 명령

 

 

 

 

방법1 - VBS 프로그램으로 윈도우10 제품키 알아내기

 

가장 추천하는 방법입니다. VB 스크립트로 된 코드를 메모장에 붙여 넣어 확장자를 vbs로 수정한 뒤 실행하면 인증된 제품 키를 표시해주고 따로 저장도 해줍니다.

아래 '더보기'를 클릭해 소스를 복사하거나, 프로그램 만드는것이 귀찮다면 아래 첨부된 "Win10 cdkey View.vbs"파일을 다운로드해 실행하면 됩니다. 소스가 공개되어 있어 위험한 일을 하지 않는 것을 확인도 가능해 안심되고 제가 해보면 가장 정확한 방법입니다.

 

Option Explicit  
 
Dim objshell,path,DigitalID, Result  
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)  
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey
'Show messbox if save to a file  
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
  Save ProductData  
End If
 
 
 
'Convert binary to chars
Function ConvertToKey(Key)
        Const KeyOffset = 52
        Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
        'Check if OS is Windows 8
        isWin8 = (Key(66) \ 6) And 1
        Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
        i = 24
        Maps = "BCDFGHJKMPQRTVWXY2346789"
        Do
                  Current= 0
           j = 14
           Do
              Current = Current* 256
              Current = Key(j + KeyOffset) + Current
              Key(j + KeyOffset) = (Current \ 24)
              Current=Current Mod 24
               j = j -1
           Loop While j >= 0
           i = i -1
           KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
           Last = Current
        Loop While i >= 0  
        
        If (isWin8 = 1) Then
           keypart1 = Mid(KeyOutput, 2, Last)
           insert = "N"
           KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
           If Last = 0 Then KeyOutput = insert & KeyOutput
        End If        
        
 
        ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
   
        
End Function
'Save data to a file
Function Save(Data)
        Dim fso, fName, txt,objshell,UserName
        Set objshell = CreateObject("wscript.shell")
        'Get current user name  
        UserName = objshell.ExpandEnvironmentStrings("%UserName%")  
        'Create a text file on desktop  
        fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
        Set fso = CreateObject("Scripting.FileSystemObject")
        Set txt = fso.CreateTextFile(fName)
        txt.Writeline Data
        txt.Close
End Function

Win10 cdkey View.vbs

0.00MB

 

 

방법2 - 키 확인 프로그램으로 윈도우 10 제품키 확인하기

 

과거부터 윈도우 OS나 오피스 프로그램 등의 제품 키를 확인해 주는 전문 프로그램이 존재했습니다. 그런 많은 인증 키를 찾는 프로그램 중에 유명한 제품은 Key Finder(키 파인더)입니다. 키 파인더 프로그램이 찾을 수 있는 제품키는 수는 1백여 개가 넘습니다. 윈도우 제품뿐만 아니라 오피스, ACDSee, 포토샵, AutoCAD, 게임, 유료 스크린세이버 까지 수많은 소프트웨어의 제품키를 찾을 수 있습니다.   

 

Key Finder 공식 홈페이지 ➤

 

keyfinder_setup.exe

0.91MB

 

단점이 있다면, 제품 키 찾는 프로그램이 종종 백신 프로그램이나 웹브라우저에서 악성 프로그램으로 차단하려고 한다는 점입니다. 매우 유명하고 오랫동안 운영하는 프로그램인도 경고할 정도로 코드가 바이러스 처럼 생겼나 봅니다. 저의 경우 크롬에서는 경고없이 넘어갔습니다. 여러분은 혹시 키 파인더를 사용할때 위험하다는 경고가 뜨더라도 놀라지 마세요. 현재까지는 키 파인더는 믿을만한 프로그램입니다. :)

 

 

 

방법3 - 레지스트 정보에서 윈도우 10 제품 키 알아내기

 

세 번째로 레지스트에 있는 정보에 윈도우 10 제품 키를 알아내는 방법입니다.

과거 많은 블로거들이 이 방법으로 윈도우 10의 CD키를 찾은걸로 글을 썼던데, 저는 원래 입력했던 제품키로 표시하지 않아서 사용하지 않는 방법입니다. 궁금하실분들을 위해 방법을 남겨둡니다.

 

사용하는 윈도우 10 PC에서 regedit를 실행하여 아래 주소의 레지스트 값이 정품 키(설치 키)라고 합니다. 

\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SoftwareProtectionPlatform

 

저는 6NCT3으로 시작하는 제품키가 백업 제품키라는데... 원래 인증받은 제품키는 아니었습니다. 여러분도 혹시 모르니 다른 방법으로도 제품키, 인증키를 찾아두시기 바랍니다.

 

 

 

 

방법4 - 브랜드 PC, 노트북을 위한 윈도우 제품 키 확인 명령

 

브랜드 PC, 노트북 중에 윈도우가 설치되어 있고 본체에 윈도우 10 정품 스티커만 붙어 있을 경우 BIOS에 OEM Product Key가 저장되어 있습니다. 이렇게 저장된 제품키는 cmd 명령 프롬프트에서 명령어를 실행하여 제품키를 알아낼수 있습니다.

 

 

윈도우 실행에서 cmd를 입력해 명령 프롬프트를 열고 아래 명령 명령어 입력하세요

wmic path softwarelicensingservice get Oa3xOriginalProductKey

 

윈도우 cmd 에 명령을 입력하면 BIOS에 제품키가 있을경우 표시된다고 합니다. 저는 브랜드 PC가 아니라서 Oa3xOriginalProductKey 라고 표시한 후 어떤 키도 표시되지 않았습니다.

 

 

 

 

여기까지 윈도우 10 설치 키, 제품키 알아내는 4가지 방법을 마칩니다..